@#INSTALL
@eventname The Troll #2
@author Donald Tidmore
@authid TROLL2-106
@codebegin
@runsub TROLL2 &filename
@codeend
@target FOREST

@#UNINSTALL

; ============================================================
;  The Troll #2 v1.06 - Adaptation by Donald Tidmore.
;   Email: ktidmore@bellsouth.net.   Fidonet:  1:123/450
;   WWW: http://camelot.legendarydragons.com/.  As of mid-June 2007.
; ============================================================
;
@#TROLL2 
@verreq 407
; ========================== Michael's notes:
; I've always wondered why a random event couldn't kill you..
; I've also wondered why there aren't as many bad guys in the random
; events.. Another funny thought. This must be a huge forest.. How
; else could there be so many monsters? :)
; The player will lose 1 to 10 hitpoints.. (and may get killed).
;
; ========================== My revision notes:
; 08/24/02 modification by Donald Tidmore.  If player has a Fairy,
; and they are killed, bring them back to life.  This script MOST
; definitely is designed ONLY for LORD v4.07.  Most comments are
; by Preslar.  I simply cleaned up his bad spelling/punctuation errors.
;  02/07/03 v1.02 - cleaned up fairy rescue code, added blank lines.
;

@set &N1 to &rnd10
@writeln
@writeln
@writeln   `%MEGA EVENT IN THE FOREST
@writeln `0-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
@writeln   `2An ugly troll jumps out from behind and tries to steal
@writeln   your coin purse!
@writeln
@set &Pht to -&N1

@if &Pht > 0 1
 @begin
   @writeln   You fend him off, but you lose `%&N1`2 hitpoints!
   @writeln
   @hitakey
 @end
@else 1      ; Added identifier 1. 04/12/05
  @begin
; If the player is smart, he won't "look for something to kill" while
; he's low on hitpoints.. If he isn't keen on the idea of protecting
; himself, well, the Troll will get him..
    @set &Pgo to 0
    @set &Pge to 0
    @set &Pdd to true

; Lord will save the player's data when he gets back from the event,
; but some unscrupulous people will drop carrier when they see that they've
; been killed. So save the player data now so they can't cheat the game.
    @saveplayer

    @writeln   You valiantly try to fend off the little troll, but at the
    @writeln   last moment, he pulls a dagger out of his boot and gives you
    @writeln   a final blow!
    @writeln
    @writeln   `2The troll made off with your coin purse and gem sack!
    @writeln
    @writeln   `@You have been killed by the Troll!
    @writeln
    @hitakey

    @if &pfa is false 2
      @begin
; @endgame really isn't needed here since lord will check the player's
; hitpoints when they get back from the event.. But, it's still an example
; of how it could be used..
        @endgame
      @end
    @else 2          ; Added identifier 2. 04/12/05
      @begin 
        @writeln   `0 = = = = = = = = = = = = = = = = = = = = = = = = = = = = = 
        @writeln   `$Suddenly there is a bright flash of light!
        @writeln
        @writeln   `!Your `0Fairy `!appears and says, "Looks like you managed to
        @writeln   `!get yourself killed!"  He taps you with a little wand,
        @writeln   `!and then flies away.
        @writeln

        @set &N10 to &Phx
        @set &Pht to &N10           ; Restore the player to life.
        @set &Pfa to false          ; Fairy is bye-bye now.
        @set &Pdd to false          ; Reset Player to Alive status.

        @writeln   `0You have been `$HEALED. `#Try not to do anything else stupid
        @writeln   `#today!  `%Wandering around the forest near death is `@NOT WISE,
        @writeln   `%when there are nasty forest monsters and the `@Troll `%around!
        @writeln
      @end
    @endif 2
 @end
@endif 1
; psst: one day, this lil bugger of a troll is going to try and make off
; with your weapon.. your armour? nah. it's hard enough to take off as it
; is. but not hard to grab your Spear of Gold and take off running...
@hitakey
@endquest

; 04/12/05: Added number identifier to the @else statements.
; 04/12/05: Changed version to 1.04. Donald.
; 07/24/05: Added INSTALL and UNINSTALL sections to script.

; v1.06: Changed Email/WWW info, and version number.