@#INSTALL
@eventname The Tax Man
@author Gordon Lewicky
@authid TAXMAN-115
@codebegin
@runsub TAXMAN &filename
@codeend
@target FOREST

@#UNINSTALL

; ===========================================================
: The Tax Man v1.15
;   Email: ktidmore@bellsouth.net.   Fidonet:  1:123/450
;   WWW: http://camelot.legendarydragons.com/.  As of mid-June 2007.
;
; Update of Gordon Lewicky's TaxMan LADY Script -- 07/25/2005
; to use INSTALL and UNINSTALL script code blocks.  Revision
; done by Donald Tidmore for my deceased friend, who died in
; early July 2005.
; ============================================================
;
@#TAXMAN
@display
`c  `%Event In The Forest`0
`l

  `2You hear huffing and puffing and the patter of little feet
  from behind you. Turning around you see a wheezing old elf
  carrying a big ledger, stumble to stand in front of you.

  `9"Zowsa... glad I caught up with you, &nick!"

  `0"And why is that?", `2you ask the old elf suspiciously.

  `9"Why, it's Taxtime again, of course!", `2grins the elf.
  `9"Lemme check my ledgers to see your account status."

  `2You stand there patiently, if not just a bit worried as well.

@enddisplay
@hitakey
@math &N1 = &Pba + 0
@math &N2 = &Pgo + 0
@math &N3 = &N1 + &N2           
@set &N7 to 0
@if &N3 > 999999 1
 @begin
 @set &N7 to 1
 @end
@endif 1
@if &N3 > 999999999 1
 @begin
 @set &N7 to 2
 @end
@endif 1
@if &N7 = 2 1
  @begin
    @math &N4 = &N1 / 2
    @math &N5 = &N2 / 2
    @set &Pba to &N4
    @set &Pgo to &N5
    @writeln
    @writeln `2You see the elf frowning and you start to worry some more.
    @writeln
    @writeln `9"Tsk, tsk!"`2, chortles the old elf.
    @writeln `9"You owe back taxes and a penalty as well. I assess 50% taxes."
    @writeln
    @writeln `0"What the..."`2 you stammer as the old elf dances away in glee.
    @writeln
    @writeln `2You suddenly feel much poorer!
  @end
@endif 1
@if &N7 = 1 1
  @begin
    @math &N4 = &N1 / 10
    @math &N5 = &N2 / 10
    @math &N6 = &N1 - &N4
    @set &Pba to &N6
    @math &N6 = &N2 - &N5 
    @set &Pgo to &N6
    @writeln
    @writeln `2The elf looks up with a smile and your worries lessen.
    @writeln
    @writeln `9"Hmmm... You only need to pay this years taxes."`2, says the old elf.
    @writeln `9"I'm glad you keep your taxes paid up to date. I assess 10% taxes."
    @writeln
    @writeln `0"Argggg..."`2, you whisper, as you wipe the sweat off your brow.
    @writeln
    @writeln `2The elf turns away and vanishes but still your purse feels lighter!
  @end
@endif 1 
@if &N7 = 0 1
  @begin
    @set &Phi to true
    @writeln
    @writeln `2The elf turns this page and that, then does it again.
    @writeln
    @writeln `9"Well now!"`2, exclaims old elf.
    @writeln `9"You are much too poor to pay taxes, Have a nice day."
    @writeln
    @writeln `0"Whew..."`2, you gasp as the old elf trudges away.
    @writeln
    @writeln `2You stand there feeling much better and are in `@High Spirits!
  @end
@endif 1
@writeln `2
@hitakey
@clrscr
@endquest

; ============================================================
; Taxman by Gordon Lewicky, Sysop - Milky Way, 1:153/307
; 13 Apr/02
;
; This event was written and tested using Lord v4.07á 31 Mar/02 but
; any commands/vars are from previous Lords. This supports v4.05 & up.
;
; This event is designed to help with the overflow error when
; a player gets too much gold. It tests for a total in hand
; and in the bank for > 1 bil, and <= 1 bil. If the player
; has more then a bil, then he gets taxed 50% of all gold.
; If the player is over a mil then they get taxed at 10%
; If they have 1 mil or less, they get off scott free and are
; set to High Spirits. :)
;
; Since the max weapon and armor together cost less then a bil
; anything more is basically wasted and puts the user into the
; overflow error range. Since it is random, it's not too much
; of a hardship. If a player is smart, they'll spend their
; gold over a bil, just to keep out of the overflow range.
;
; ============================================================

; Version 1.10: Added INSTALL, UNINSTALL code blocks. 07-25-05.
; 05/31/07: v1.15: Added Email/WWW info; Changed version #.