@#INSTALL
@eventname Sharpen Weapon
@author Donald Tidmore
@authid SHARPEN-WEAPON-114
@codebegin
@runsub SHARPEN &filename
@codeend
@target FOREST

@#UNINSTALL

; =================================================================
; Sharpen Weapon v1.14.  Script Event by Donald Tidmore.
;   Email: ktidmore@bellsouth.net.   Fidonet:  1:123/450
;   WWW: http://camelot.legendarydragons.com/.  As of mid-June 2007.
; Requires LORD v4.05+
; =================================================================
;
@#SHARPEN
@display
`c                 `$Event In The Forest`0
`l
  `%You find a clearing with a cabin, and see a BlackSmith sharpening
  weapons by a forge.  He says that he'll give your weapon a quick going
  over for free.

  You accept his offer, and hand over your `$&Pwe`%. He looks it
  over, and fixes it up.  When he returns it to you, it looks nearly
  as good   as when you bought it at the `#Weapons Shop.
@enddisplay

; 10/25/02: Negative value handling.
@if &Psr < 0 1
  BEGIN
    @math &N10 = &Psr * -1
    @set &Pde to &N10
    @writeln   `@Note: `%Negative Strength points detected.
    @writeln   `%Your Strength points have been reset to positive amount.
    @writeln   `%You should now have `@&N10 `!Strength points.
  END
@endif 1

@math &N1 = &Psr + 0         ; Store current Strength points.
@math &N2 = &Plv * 5         ; Compute reward amount.

@if &N2 > 30 2
  @set &N2 to 30             ; Limits rewards to 30 points, max.
@endif 2

@math &N3 = &N1 + &N2        ; add new points to Strength field

; ------------------------------------------------------------------
@if &N3 > 32000 3            ; Revised code 12/30/2003.
  @begin
    @math &N10 = 32000 - &N1      ; Recompute Strength reward.
    @set &Psr to 32000            ; Resets Strength stat to 32,000.
    @set &N3 to 32000             ; Reset Strength storage var to 32,000.
    @set &N2 to &N10              ; Reset Reward amount variable.
    @writeln
    @writeln     `#Note: `!Script will not raise `0Strength `!over 32,000 points.
  @end
@endif 3
@set &Psr to &N3             ; Reset Strength Points stat.

; ------------------------------------------------------------------
@writeln
@writeln   `$ATTACK POWER `0RAISED `%by `@&N2 `$points.
@writeln
@writeln     `%You now have `!&N3 `$Strength points.
@writeln

@hitakey                   ; Needed for LORD 4.06 compatibility.

@endquest

; =================================================================
; Get your Weapon sharpened by a blacksmith for free.  Your reward
; is 5 Strength points * Game Level.
;
; v1.02: Changed to allow 4 Strength points, instead of 3.
; v1.03: Tested script under LORD 4.06.
; v1.04: Added negative Strength points correction code. 10/25/02.
; v1.10: 05/17/2003. Changed formula to 4 AS points * Game level.
;        Actual reward is limited to 24 Strength points.
; v1.11: 12/27/2003. Prevents Strength from exceeding 32,000 points.
;        Changed formula to 5 Strength points * Level.
;        Changed reward limit to 30 Strength points.
; v1.12: 12/30/2003. Fixed to display actual amount of Strength awarded,
;        where it is below the computed amount normally awarded.
; 07/24/05: Added INSTALL and UNINSTALL sections to script.

; 05/31/07: v1.14: Revised Email/WWW info;  Changed version #.