@#INSTALL
@eventname The Ruined Castle
@author Dan Stovall
@authid RUINED-CASTLE-112
@codebegin
@runsub RUINCAST &filename
@codeend
@target FOREST

@#UNINSTALL

; ===============================================================
; Ruined Castle Event v1.12  By Dan Stovall.  Email: sysop@bobobbs.net
; ===============================================================
;
@#RUINCAST       ;07/24/05: Changed from RUINEDCASTLE.
@clrscr
@writeln `l
@writeln `c  `6You travel even deeper into the forest, and discover an old ruined castle.
@writeln `l
@writeln
@writeln `7You approach the `6rusted `7iron gate.
@writeln
@writeln `%What would you like to do?
@writeln `9[`7E`9]`%nter the castle
@writeln `9[`7W`9]`%alk around to the side of the castle
@writeln `9[`7L`9]`%eave this place
@choice EWL `%Your command? [EWL]
@case response 1

E: @begin
     @writeln
     @writeln `7You pull open the gate, and enter the castle.
     @writeln
     @writeln `7As you walk along the darkened corridor, you begin to hear strange noises...
     @writeln
     @writeln `7You reach the end, where you see the spirit of a long dead nobleman.
     @hitakey
     @clrscr

     @writeln `l
     @writeln                 `4In the Presence of the Spirit of the Castle
     @writeln `l
     @writeln
     @writeln `4The spirit whispers... "Why have you entered my castle?"
     @writeln `9[`7G`9]`%ive me `$GOLD`%!
     @writeln `9[`7K`9]`%nowledge is power, that is what I seek!
     @writeln `9[`7F`9]`%orgive my intrusion, kind spirit, I will leave you in peace.
     @choice GKF `%What is your response to the spirit?
     @case response 2
       ; 04-16-02 change: Each section uses identical N1-N4 variables
       ; for the purposes needed in each code block.

     G: @begin
          @writeln
          @math &N1 = &rnd500 + 250
          @math &N2 = &N1 * &Plv
          @writeln `4 "Take the `$gold `4and leave!"
          @writeln `%A chest opens in the corner of the room...there's &N2 `$gold `%in it!
          @writeln

          @math &N3 = &Pgo + 0
          @math &N4 = &N2 + &N3
          @set &Pgo to &N4
          @hitakey
       @end

     K: @begin
          @writeln
          @math &N1 = &rnd50 + 25
          @math &N2 = &N1 * &Plv
          @writeln `4 "You desire knowledge?  Very well...
          @writeln
          @writeln `4You hear his thoughts in your head...and you faint!
          @writeln
          @hitakey

          @writeln `9You awake outside the castle, feeling more experienced.
          @writeln
          @writeln `9You've gained `%&N2 `9experience points!
          @writeln

          @math &N3 = &Pex + 0
          @math &N4 = &N3 + &N2
          @set &Pex to &N4
        @end

     F: @begin
          @writeln
          @math &N1 = &rnd1 + 2
          @math &N2 = &N1 * &Plv
          @writeln `4 "Very well...I wish you safe travels."
          @writeln
          @hitakey

          @writeln `%You leave the spirit's castle, and return to the forest.
          @writeln  Somehow you feel different and healthier.
          @writeln

          @math &N3 = &Phx + 0
          @math &N4 = &N2 + &N3
          @set &Phx to &N4
        @end
     @endcase 2              ; End of Ghost response routine.
   @end

W: @begin
     @writeln
     @writeln `%You walk around to the side of the castle.
     @writeln
     @writeln `%As you reach the corner, you see...
     @writeln
     @hitakey

     ; 04-16-02 Change: Case #1 already used; switch to use 3.
     ; 04-20-02: Corrected by Gordon Lewicky to use &N7.
     ; ------------------------------------------------------
     @set &N7 to &rnd3
     ;  Corrected code to avoid Lord crashes from unexpected random
     ;  number selection by LORD script engine.
     @if &N7 = 0 1
       @begin
         @set &N7 to 1
       @end
     @endif 1                ; Error trap for 0 rand var. selection

     @case &N7 3
     1: @begin
          @writeln
          @set &N8 to 1
          @writeln `%...a frightened child!
          @writeln `%The child seems willing to join you, and you welcome the company.
          @writeln

          @math &N8 = &N8 + &Pki
          @set &Pki to &N8
          @hitakey
        @end

     2: @begin
          @writeln
          @math &N9 = &rnd3 + 2
          @writeln `%...&N9 gems!
          @writeln `%You gather up the gems, and return to the forest.

          @math &N10 = &N9 + &Pge
          @set &Pge to &N10
          @hitakey
        @end

     3: @begin
          @if &Pho is false 1
            @begin
              @writeln `%...a beautiful horse!
              @hitakey
              @writeln `%It doesn't seem to have an owner, so you mount up.
              @writeln
              @hitakey
              @set &Pho to true
            @end
          @else 1           ; 04/12/05: added identifier 1
            @begin
              @writeln
              @set &N8 to 1
              @writeln `%...a frightened child!
              @writeln `%The child seems willing to join you, and you welcome the company.
              @writeln

              @math &N8 = &N8 + &Pki
              @set &Pki to &N8
              @hitakey
            @end
          @endif 1
        @end
     @endcase 3
   @end                      ; End of Walk inside Castle routine.

L: @begin
     @writeln
     @writeln `6As you walk back, you notice that the path diverges in two in the wood...
     @writeln `%Do you go right or left?
     @writeln `9[`%R`9]`%ight...I like to stay on the path I know.
     @writeln `9[`%L`9]`%eft...I'll take the one less traveled by.
     @choice RL `%Your choice?
     @case response 4

     R: @begin
          @writeln `%You stay on the familiar path, and return to the forest.
        @end

     L: @begin
          @clrscr
          @writeln `l
          @writeln                          `6On the Path Less Traveled By
          @writeln `l
          @writeln
          @writeln
          @writeln `%Ah...this path is grassy, and wanting wear...
          @writeln
          @writeln `6The path is overgrown with `#f`$l`#o`$w`#e`$r`#s`@...
          @writeln
          @hitakey

          @writeln `6You come to a clearing, where a solitary tree stands.
          @writeln
          @writeln `6You decide to rest in the peace and quiet of this secluded spot.
          @writeln
          @hitakey

          @math &N11 = &rnd5 + 2
          @writeln `6You awake some time later feeling rested...
          @writeln
          @writeln `6You feel like you could fight `%&N11 `6more times in the forest!
          @writeln
          @hitakey

          @writeln `6Taking this path has made all the difference.
          @writeln
          @math &N12 = &N11 + &Pff
          @set &Pff to &N12
        @end
     @endcase 4              ; End of tree in clearing routine.
@endcase 1              ; End of original Enter, Walk, Leave routine.

@endquest

; ===============================================================
; WWW: http://www.bobobbs.net.  Script title/label name was changed
; from Events to RUINEDCASTLE.
;
; The Ruined Castle v2.00 LORD IGM:  Available from this URL:
; http://www.filegate.net/camelot/lordfile/ruin20.zip - 10/07/03 note.
;
; The Ruined Castle v2.20 LORD IGM:  Available from this URL:
; http://www.filegate.net/camelot/lordfile/ruin22.zip - 12/05/04 note.
;
; The Ruined Castle: In Beta development as of 05/31/2007.
; http://camelot.legendarydragons.com/IGM-Beta/ruinwork.zip

;   Version 1.10: Use of number identifiers with @else entries. DGT.
;
; 04/12/05: Added number identifier to the @else statements.
; 04/12/05:  Added version 1.10 notation. Donald Tidmore.
; 07/24/05: Added INSTALL and UNINSTALL sections to script.

; 05/31/07: Added info for current IGM beta access.
; 05/31/07: Changed version to 1.12. (Donald Tidmore)