@#INSTALL
@eventname Polish Armour
@author Donald Tidmore
@authid POLISH-ARMOUR-114
@codebegin
@runsub POLISH &filename
@codeend
@target FOREST

@#UNINSTALL

; ==============================================================
; Polish Armour v1.14.  Script Event by Donald Tidmore.
;   Email: ktidmore@bellsouth.net.   Fidonet:  1:123/450
;   WWW: http://camelot.legendarydragons.com/.  As of mid-June 2007.
; ==============================================================
;
@#POLISH
@display
`c                 `$Event In The Forest`0
`l
  `%You find a clearing with a cabin, and see a Blacksmith working on
  several suits of Armour.  He's beating dents out, and giving the Armour
  a new polish.  Looking up at you, he checks out your Armour, and offers
  to give yours a quick polishing for free.

  You accept his offer, and hand over your `$&Par`%. He looks it
  over, and fixes it up.  When he returns it to you, it looks nearly as
  good as when you bought it at the `#Armoury.
@enddisplay

; 10/25/02: Negative value handling.
@if &Pde < 0 1
  BEGIN
    @math &N10 = &Pde * -1
    @set &Pde to &N10
    @writeln   `@Note: `%Negative Defense points detected.
    @writeln   `%Your Defense points have been reset to positive amount.
    @writeln   `%You should now have `@&N10 `!Defense points.
  END
@endif 1

@math &N1 = &Pde + 0         ; Store current Defense points.
@math &N2 = &Plv * 6         ; Compute reward amount. 12/27/03.

@if &N2 > 40 2               ; 12/27/03: Changed limit to 40 points.
  @set &N2 to 40             ; Limits rewards to 40 points, max.
@endif 2

@math &N3 = &N1 + &N2        ; add new points to Defense field

; ------------------------------------------------------------------
@if &N3 > 32000 3            ; Revised code 12/30/2003.
  @begin
    @math &N10 = 32000 - &N1      ; Recompute defense reward.
    @set &Pde to 32000            ; Resets Defense stat to 32,000.
    @set &N3 to 32000             ; Reset Defense storage var to 32,000.
    @set &N2 to &N10              ; Reset Reward amount variable.
    @writeln
    @writeln     `#Note: `!Script will not raise `0Defense `!over 32,000 points.
  @end
@endif 3
@set &Pde to &N3             ; Reset Defense Points stat.

; ------------------------------------------------------------------
@writeln
@writeln   `$DEFENSE POWER `0RAISED `%by `@&N2 `$points.
@writeln
@writeln     `%You now have `!&N3 `$Defense points.
@writeln

@hitakey                   ; Needed for LORD 4.06 compatibility.

@endquest

; ==============================================================
; Get your Armour cleaned up and polished.  Your reward is 5
; free Defense points * Game Level.  Requires LORD v4.05+.
; v1.03: Tested script under LORD 4.06.
; v1.04: Added negative Defense points correction code. 10/25/02.
; v1.10: 05/17/2003. Changed formula to 5 DS points * Game level.
;        Actual reward limited to 30 defense points.
; v1.11: 12/27/2003. Prevents Defense from exceeding 32,000 points.
;        Changed formula to 6 defense * Level. Limit changed to 40 points.
; v1.12: 12/30/2003. Fixed to display actual amount of Defense awarded,
;        where it is below the computed amount normally awarded.
; 07/24/05: Added INSTALL and UNINSTALL sections to script.
; 05/31/07: v1.14: Revised Email/WWW info;  Changed version #.