@#INSTALL
@eventname The Nice Hag
@author Donald Tidmore
@authid NICEHAG137
@codebegin
@runsub NICEHAG &filename
@codeend
@target FOREST

@#UNINSTALL

; =================================================================
; The Nice Hag v1.37:  By Donald Tidmore.
;   Email: ktidmore@bellsouth.net.   Fidonet:  1:123/450
;   WWW: http://camelot.legendarydragons.com/.  As of mid-June 2007.
; Script requires LORD v4.05+.
; ===============================================================
;
@#NICEHAG
@display
`c  `!          Extraordinary Encounter In The Forest
`l
  `%While adventuring in the `0Forest, `%you come across an `#Old woman.
  `%Her smile warms your heart.  `!"My name is `#Sarah, `!and I'm lost.
  `!Can you help me get home?" `%she asks you.   Being a good warrior,
  you escort her home to a little brick cottage near town.  You are
  greeted by `#Sarah's `%sister, who you have met before -- it's the
  `@Old Hag.  `0(Who in this script is now known as `!"The Nice Hag.`0)

  `%She thanks you for bringing her sister `#Sarah `%home safely, and
  offers you a special deal as a reward.  For `!one `0Gem, `%she will
  `@DOUBLE `%her usual exchange rate, and give you `$TWO `0Max HitPoints!
@enddisplay

; 05/15/2007: Deleted debug lines that are no longer needed.
;
; Establish all Global variables used by NiceHag.Ldy:
; ---------------------------------------------------------------
@math &N1 = &Pge + 0         ; Store player's Gems on Hand.
@math &N2 = &Pht + 0         ; Store current HitPoints.
@math &N3 = &Phx + 0         ; Store current Max HitPoints.
@math &N4 = &Pde + 0         ; Store current Defense Points.
@math &N5 = &Pex + 0         ; Store current Experience Points.
@math &N6 = &Pgo + 0         ; Store current Gold in Hand.
@math &N7 = &Plv + 0         ; Store player's game Level (1-12).
@math &N8 = &Psr + 0         ; Store current Strength points.

; Pre-set NumVars used in Healing section, for use in Show Rewards
; section.  N12 for awarded Strength points;  N16 for awarded Gold
; from healing Temporary HitPoints.
; ----------------------------------------------------------------
@math &N12 = 0               ; Pre-set for Strength points handling.
@math &N16 = 0               ; Pre-set for Temp HP/Gold handling.

@math &N25 = 0          ; 12/21/03: use for temp result handling
; ----------------------------------------------------------------


@LABEL Fix_Bad_Stats         ; Added section 03/21/2007.
; --------------------------------------------------------
@if &N1 > 32000 1            ; Fix Over-Range Gems stat.
  @begin
    @Set &N1 to 32000
    @Set &Pge to 32000
    @writeln
    @Writeln  `@Notice:  `!Reset Over-Range Gems down to 32,000.
  @end
@endif 1

@if &N2 > 32000 2            ; Fix Over-Range Hit-Points stat
  @begin
    @Set &N2 to 32000
    @Set &Pht to 32000
    @writeln
    @Writeln  `@Notice:  `!Reset Over-Range Hit-Points down to 32,000.
  @end
@endif 2

@if &N3 > 32000 3            ; Fix Over-Range Max HitPoints stat
  @begin
    @Set &N3 to 32000
    @Set &Phx to 32000
    @writeln
    @Writeln  `@Notice:  `!Reset Over-Range Max HitPoints down to 32,000.
  @end
@endif 3

@if &N4 > 32000 4            ; Fix Over-Range Defense Points stat
  @begin
    @Set &N4 to 32000
    @Set &Pde to 32000
    @writeln
    @Writeln  `@Notice:  `!Reset Over-Range Defense Points down to 32,000.
  @end
@endif 4

@if &N5 > 2000000000 5       ; Fix Over-Range Experience Points stat
  @begin
    @Set &N5 to 2000000000
    @Set &Pex to 2000000000
    @writeln
    @Writeln  `@Notice:  `!Reset Over-Range Experience Points down to 2 Billion.
  @end
@endif 5

@if &N6 > 2000000000 6       ; Fix Over-Range Gold in Hand stat
  @begin
    @Set &N6 to 2000000000
    @Set &Pgo to 2000000000
    @writeln
    @Writeln  `@Notice:  `!Reset Over-Range Gold in Hand down to 2 Billion.
  @end
@endif 6

@if &N7 > 32000 7       ; Fix Over-Range Strength Points stat
  @begin
    @Set &N7 to 32000
    @Set &Psr to 32000
    @writeln
    @Writeln  `@Notice:  `!Reset Over-Range Strength Points down to 32,000.
  @end
@endif 7
@hitakey
; =======================================================


;  Determine if player has an Gem to give to the Hag.
;  ------------------------------------------------------------
@if &N1 > 0 1
   @goto HAG_GEMS            ; Player has at least 1 Gem.
@else 1              ; 04/12/05: added identifier 1.
   @goto HAG_NOGEMS          ; Player has no gems.
@endif 1
@goto HAG_STATS              ; Error trap usage only.


; ----------------------------------------------------
@LABEL HAG_GEMS              ;  Ask player for the gem, etc.
@writeln   `@ - - - - - - - - - - - - - - - - - - - - - -
@writeln
@choice YN     `$So warrior, do you have a `0Gem `$for me?`@ [Y`%/`9N`@]
@writeln

@case response 1
  Y: @begin               ; Process player's giving Gem to Hag.
       @display
  `@ - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  `%You hand her your `0Gem, `%and she says, `!"Thank you, `$&nick."
  `%Taking an `0Emerald wand `%out of a pocket, she waves it over you.

    You feel a `$small surge of `9Health `%in your body.
       @enddisplay

       @math &N10 = &N1 - 1     ; Deduct 1 Gem from Gems on Hand
       @set &Pge to &N10        ; Reset Gems on Hand
       ; ------------------------------------------------------

       @if &Phx < 31999 2         ; 12/20/03: do only if Max HP below 31,999.
         @begin
           @math &N11 = &N3 + 2   ; Add 2 HitPoints to Max HP
           @set &Phx to &N11      ; Reset adjusted Max HitPoints
           @set &N3 to &N11       ; Reset Max HP storage value. 12/21/03

           @writeln
           @writeln        `$Max HitPoints `@RAISED `$by `02 Points.
           ; -----------------------------------------------------------
           @writeln               ; 12/21/03
           @writeln        `!You now have `0&N11 `#Max Hit-Points.  ; 12/21/03
           ; -----------------------------------------------------------
           @writeln
           @hitakey
           @cls
         @end
       @else  2              ; 04/12/05: added identifier 2.
         @begin                ; 12/20/03: added new ELSE code block.
           @goto HAG_NOREWARD      ; verified 3:44 pm 12/20/03
         @end
       @endif 2

     @goto HAG_HEALING
     @end     ; Ending of Y case response handling.

  ; Process user's decision to pass on offer.
  ; ----------------------------------------------------------
  N: @begin                ; Start 2nd code block
       @writeln
       @display
  `0Thanks ma'am, but I want to keep my Gem for later. `!"That's OK.
  You might want to give it your girlfriend, perhaps," `%the Hag says.
       @enddisplay
; 09/09/04: Show player's words in Lt. Green, Hag's words in Lt. Cyan.

       @math &N10 = &N1 + 0     ; No change in Gems on hand.
       @set &Pge to &N10        ; Reset Gems on Hand
       ; ------------------------------------------------------
       @math &N11 = &N3 + 0     ; No Max HitPoints are given.
       @set &Phx to &N11        ; Reset adjusted Max HitPoints
       @set &N3 to &N11         ; Reset Max HP storage value. 12/21/03
     @end
@endcase 1
@goto HAG_HEALING           ; Jump past the HAG_NOGEMS code section


@LABEL HAG_NOREWARD         ; Created 12/20/03
@math &N11 = &Phx + 0       ; verified 3:44 pm 12/20/03
@writeln
@writeln     `!"Sorry, but I can not help you today, `$&nick`%.
@writeln     `!Because, you already have `!&N11 `$Max Hit-Points," `%she says.
@writeln          ; 09/09/04: Display quoted wording in Lt. Cyan.
@hitakey
@cls

@goto HAG_HEALING


; ----------------------------------------------------
@LABEL HAG_NOGEMS          ;  Ask player for the gem, etc.
  @writeln
  @display
  `%Your pockets are empty. `!"No `0Gems `!today, I see.  Well I'll
  give you `$ONE `!Free `0Max Hitpoint `!anyway," `%the Hag says.
  @enddisplay
  ; 09/09/04: show quoted wording in Lt. Cyan.

  @math &N10 = &N1 + 0     ; No change in Gems on hand.
  @set &Pge to &N10        ; Reset Gems on Hand
  ; ------------------------------------------------------

  @if &Phx < 32000 3         ; 12/20/03: do only if Max HP below 32,000.
    @begin
      @math &N11 = &N3 + 1   ; Add 1 HitPoint to Max HP
      @set &Phx to &N11      ; Reset adjusted Max HitPoints
      @set &N3 to &N11       ; Reset Max HP storage value. 12/21/03
      @writeln
      @writeln   `$Max HitPoints `@RAISED `$by `01 Point.
      ; -----------------------------------------------------------
      @writeln
      @writeln   `!You now have `0&N11 `#Max Hit-Points.  ; 12/21/03
      ; -----------------------------------------------------------
      @writeln
      @hitakey
    @end
  @else  3              ; 04/12/05: added identifier 3.
    @begin             ; 12/20/03: added new ELSE code block.
      @set &N11 to 32000     ; 12/27/03: Reset temp var.  (REQUIRED)
      ; Prevents LADY script engine from setting Current HP to zero.

      @set &Phx to 32000     ; 12/27: Reset Max HitPoints to 32,000.
      @set &N3 to 32000      ; Reset Max HP storage value. 12/27/03
      @writeln
      @writeln     `@Sorry, I can not help you today, `$&nick`%.
      @writeln     `!Because, you already have `0&N11 `$Max Hit-Points.
      @writeln
      @hitakey
    @end
  @endif 3
; --------------------------------------------------------------------

  @writeln
  @display
  `@ - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  `%She waves an `0Emerald crystal wand `%over your body. You feel a
  `0little `$HEALTHIER `%now.

    `!Your `@Max HitPoints `!were raised by `#1 `!point.  ;12/27/03
    `!You now have `$&N3 `@Max Hit-Points, `#&nick.       ;12/27/03
  @enddisplay


;  Give player a Free Healing, or Some Experience points, if
;  no healing is needed.
; ---------------------------------------------------------------
@LABEL HAG_HEALING
@if &N2 < &N3 4        ; Healing Scenario #1: Std healing routine
  @begin                               ; Start 4th code block
    @set &Pht to &N11        ; Reset current HP to equal new Max HP.
    @writeln   

    @if &N11 > 32000 5       ; Fix bug in LADY script language. 10/29/02.
      @begin
        @set &Pht to 32000
        @set &N11 to 32000
        @set &N3 to &N11       ; Reset Max HP storage value. 12/21/03
      @end
    @endif 5

    ; -----------------------------------------------------------------
    @if &N2 = 0 6           ; 12/20/03: make sure script doesn't kill player.
      @begin                ; if anything goes wrong with Hitpoint handling.
        @math &N2 = &Pht + 0
        @math &N3 = &Phx + 0

        @writeln  `!"Oops. Looks like your `%Hit-Points `!dropped to `@Zero`%!!`!"  ;Added 05/31/07
        @writeLn  `!"So we'll just take care of that problem right now."  ;Added 05/31/07

        @Set &Pht to &Phx

        @writeln                ; 05/31/07
        @writeln  `!"She restores you to full vibrant health."  ; 05/31/07
        @writeln                ; 05/31/07
      @end
    @endif 6
    ; -----------------------------------------------------------------

    @display
  `@ - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  `!"You look a little tired to me," `%the Hag says.  She pulls a `9Blue
  Sapphire wand `%out of a pocket, and waves it over you.  `!"There you go,
  no more aches and pains to bother you.  You are `0HEALED. `!Now go
  over to `$Sarah.  `!She has a present for you, I believe."`%
    @enddisplay
              ; 09/09/04: show quoted wording in Lt. Cyan.
    @goto HAG_DEFENSE
  @end
@endif 4

; Healing Scenario #2: No Healing required, give player 5 Strength
; points times Level.  N7 is player's game level. Max amount is 36 points.
; N8 stat is current Strength points amount.
; ----------------------------------------------------------
@if &N2 = &N11 4
   @begin                              ; Start 5th code block
     @math &N12 = 3 * &N7         ; Grant Variable # of Strength points.
     @math &N13 = &N8 + &N12      ; Compute new Strength points total

     ; -----------------------------------------------------------------
     ;     Is N13 value for Strength points above 32,000 points?
     ;     Uses N25 for temp result handling of Strength points stat.
     ; -----------------------------------------------------------------
     @if &N13 > 32000 5           ; Keep Strength below 32,000. 12/21/03.
       @begin
         @math &N25 = 32000 - &N8      ;Recompute Strength points reward.
         @set &N13 to 32000            ;Reset new Strength amount to 32,000.
         @set &N12 to &N25             ;Reset strength award to new value.
       @end
     @endif 5
     ; -----------------------------------------------------------------

     @set &Psr to &N13            ; Reset Strength Points stat.

     @math &N14 = &N13 + 0  
     @set &N8 to &N14            ;   Resets N8 variable for Strength.
     @writeln
     @display
  `@ - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  `!"I see you're in perfect health today," `%the `2Nice Hag `%says.  She pulls
  a `@red Ruby wand `%out of a pocket, and waves it over you.  `!"I think
  a heroic warrior like you could use some `0Strength points. `!Your
  `$&Pwe `!will be more useful now against those awful monsters
  that roam the `3dark Forest."                 ;12/27/03 reworded sentence.
              ; 09/09/04: show quoted wording in Lt. Cyan.

      `0You `@GAIN `$&N12 `#Strength Points.    ; Verified 7:20 pm 12/21/03.

      `!You now have `0&N13 `#Strength Points.  ; 12/21/03

  `!"Now, `0&nick, `#Sarah `!has a surprise for you."  `%Feeling grateful,
  you give the `#Hag `%a kiss on her wrinkled cheek.  She's smiling as
  you walk across the room to `!Sarah, `%wondering what her present is.
     @enddisplay
              ; 09/09/04: show quoted wording in Lt. Cyan.
     @hitakey
     @goto HAG_DEFENSE
   @end
@endif 4

; ----------------------------------------------------------------
; Scenario #3: Player has Temporary HitPoints. LORD, at Level 11, gives
; 55 gold per HP healed.  So I am going to go with 65 gold per point.
; Changed to 90 gold/point on July 11, 2002.
; Changed to award Gold on basis of Game Level * 7. 05/12/2003.
; ----------------------------------------------------------
@if &N2 > &N11 4                      ; Compare Current HP to Max HP.
   @begin                         ; Start 6th code block
     @math &N15 = &N2 - &N11      ; Determine how many Temp HP to process.
     @math &N16 = &Plv * 7        ; Compute Temp HP for Gold payment rate.
     @math &N17 = &N15 * &N16     ; Compute amount of Gold to pay player.
     @math &N18 = &N6 + &N17      ; Update Gold in Hand stat.

     ; -----------------------------------------------------------------
     @if &N18 > 1999999999 5      ; Keep Gold in hand from exceeding 2 Billion. 12/21/03.
       @begin
         @math &N25 = 2000000000 - &N6      ; Determine valid payment amount
         @math &N18 = &N6 + &N25            ; Recompute Gold in Hand stat.
         @set &N6 to &N18                   ; Reset Gold in Hand to 2 Billion.
         @set &N17 to &N25                  ; Reset gold payment amount.
       @end
     @endif 5
     ; -----------------------------------------------------------------

     @set &Pgo to &N18        ; Reset adjusted Gold in Hand stat.
     @set &Pht to &N11        ; Make Current HP same as new Max HP.
     @set &N3 to &N11         ; Reset Max HP storage value. 12/21/03
     @set &N2 to &N11         ; Reset Current HP storage value. 12/21/03

     @writeln
     @display
  `@ - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  `!"I don't normally give `$Gold `!for `0Temp HitPoints `!when I heal someone.
  But, I'll make an exception for you."  `%Taking a `#Diamond wand `%out of a
  pocket, she waves it over you.

  `!"OK, `$&nick, `!you're `$HEALED". `%She hands you some `$Gold coins, `%and
  sends you over to where `#Sarah `%is sitting in a chair.
     @enddisplay
             ; 09/09/04: show quoted wording in Lt. Cyan.

     @writeln
     @writeln      `$You received `0&N17 `#Gold coins.  ;Added 05/12/2003
     ; -------------------------------------------------------------------
     @writeln
     @writeln      `$You currently have `0&N18 `#Gold in Hand.  ; 12/21/2003
     ; -------------------------------------------------------------------
     @hitakey
   @end
@endif 4


;  Give player Sarah's reward:  5 Defense points. (Changed 08/16/02.)
; ---------------------------------------------------------------
@LABEL HAG_DEFENSE
@set &N12 to 5               ; 12/21/03: use N12 to store 5 points reward.
@math &N20 = &N4 + &N12      ; Give player 5 Defense points.

; -----------------------------------------------------------------
@if &N20 > 32000 5           ; Keep Defense below 32,000. 12/21/03.
  @begin
    @math &N12 = 32000 - &N4      ;Recompute Defense points reward.
    @set &N4 to 32000             ;Reset Defense to 32,000.
    @set &N20 to 32000            ;Reset temp Defense var to 32,000.
  @end
@endif 5
     ; -----------------------------------------------------------------

@set &Pde to &N20            ; Reset Defense points stat.
@set &N4 to &N20             ; Reset Defense points storage value. 12/21/03
@writeln
@display
  `@ - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  `%When you reach `#Sarah, `%she hands you a drink.  It is `9blue, `%and it
  sparkles in the light.  After you drink it, you feel the `@Defensive
  `%power of your `$&Par `%increase.  You give `#Sarah `%a hug to 
  thank her for the precious gift.
@enddisplay

@writeln
@writeln      `$You `@GAIN `!&N12 `0Defense Points.    ; 12/21/2003
@writeln
@writeLn      `$You now have `!&N20 `0Defense Points.  ; 12/20/03
@hitakey                          ; verified 3:45 pm 12/20/03


; 04/20/2002: Add a third reward to help players obtain needed
;     Experience Points.  04/25/02 Notes: Changed to grant players
;     varying amount of Exp. points, based upon percentage of what
;     is required to reach the next Game level.  N7 stores the
;     player's current Level.
; ----------------------------------------------------------------
@label HAG_WISDOM
@case &N7 2
1: @begin
     @set &N21 to 20           ; Levels 1-3: used 1/5th formula
   @end

2: @begin
     @set &N21 to 80
   @end

3: @begin
     @set &N21 to 200
   @end

4: @begin                      ; Levels 4-5: used 1/10th formula.
     @set &N21 to 400
   @end

5: @begin
     @set &N21 to 1000
   @end

; -------------------------------------------------------------------
; 12/21/03 revision: Grant player approximate value of 5 encounters
; with each level's toughest monster. E.g. 5 meetings with Dinosaur
; at Level 7 would grant player around 6,000 points.  Script just
; grants them similar amount in one batch.
; -------------------------------------------------------------------

6: @begin
     @set &N21 to 2800         ; 12/21: approx value of 5 Belar kills.
   @end

7: @begin
     @set &N21 to 6000         ; 12/21: approx value of 5 Dinosaur kills.
   @end

8: @begin
     @set &N21 to 32000        ; 12/21: approx value of 5 King Vidion kills.
   @end

9: @begin
     @set &N21 to 65000        ; 12/21: approx value of 5 Gollums Wrath kills.
   @end

10: @begin
     @set &N21 to 125000       ; 12/21: approx value of 5 Kill Joy kills.
    @end

11: @begin
     @set &N21 to 240000       ; 12/21: approx value of 5 Cyclops Warrior kills.
    @end

12: @begin
     @set &N21 to 500000       ; 12/21: approx value of 5 Great Ogre kills.
    @end
@endcase 2

@math &N22 = &N5 + &N21       ; Compute new Exp. points total

; -----------------------------------------------------------------
@if &N22 > 2000000000 6       ; Keep Experience from exceeding 2 Billion. 12/21/03.
  @begin
    @math &N25 = 2000000000 - &N5      ; Determine valid payment amount
    @math &N22 = &N5 + &N25            ; Recompute Experience stat.
    @set &N5 to &N22                   ; Reset Experience to 2 Billion.
    @set &N21 to &N25                  ; Reset Exp. Reward field
  @end
@endif 6
; -----------------------------------------------------------------

@set &Pex to &N22             ; Reset Experience Points stat.
@set &N5 to &N22              ; Reset storage value for Experience

; 04/25/02: Current compile of Lord, during forest fights allows
; Lady script and regular fights to advance Experience past 2 billion.
; May need to add error trap code here at later time.
; -----------------------------------------------------------------
@writeln

@display
  `@ - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  `%The `0Nice Hag `%walks over to `#Sarah's `%side, and they whisper awhile
  to each other.  Smiling, `#Sarah `%says, `!"We've decided to give you
  one more gift for those gentle kisses and hugs you've given us."`%

  Pulling an `2Emerald crystal `%out of her pocket, `#Sarah `%hands it 
  to you. `!"Look deeply inside the crystal, `$&nick." `%After a
  couple of minutes, she says, `!"For your `$courteous behavior, `!we
  are granting you some valuable `0WISDOM, `!which will aid you on
  your quest."`%

  `%Thanking them for their gifts, you give each lady a good hug.
  Then you leave, ready to find and slay some more villainous 
  monsters in the `2Forest.
@enddisplay     ; 09/09/04: show WISDOM in Lt. Green.

@writeln
@writeln      `$You `@GAIN `!&N21 `0Experience Points!   ;Added 12/20/2003
@writeln
@writeLn      `%You now have `!&N22 `$Experience Points.  ; 12/20/03

; =====================================================================
@writeLn                     ; 12/21/03 code block
@case &N7 3
 1: @writeln    `0"Good luck fighting `!Bran the Warrior".
 2: @writeln    `0"Good luck fighting `!Brorandia the Viking".
 3: @writeln    `0"Good luck fighting the `!Winged Demon of Death.
 4: @writeln    `0"Good luck fighting the `!Rock Man".
 5: @writeln    `0"Good luck fighting the `!Silent Death".
 6: @writeln    `0"Good luck fighting the evil `!Black Soul".
 7: @writeln    `0"Good luck fighting the nasty `!Massive Dinosaur".
 8: @writeln    `0"Good luck fighting the ornery `!King Vidion".
 9: @writeln    `0"Good luck fighting the vicious `!Gollums Wrath".
10: @writeln    `0"Good luck fighting the evil `!Kill Joy".
11: @writeln    `0"Good luck fighting the awesome `!Cyclops Warrior".
12: @writeln    `0"Good luck fighting the `!Great Ogre `%and the `@RED DRAGON!".
@endcase 3

@hitakey                          ; verified 3:45 pm 12/20/03


; ------------------------------------------------------------------
; Show player what they received from this interesting adventure:
; ------------------------------------------------------------------
@LABEL HAG_STATS
; Revised 04/18/02 with the IF logic code.
; Second revision on 04/20/02 to incorporate Exp. points gift.
; Third revision on 04/25/02. Added Strength points line, and
; modified Scripts's Num Vars to new consistent number use.
; Change to always show Strength points data to player.
; 10/29/02: Add bug fix to cover LORD reporting above-range values
;   for HitPoints, Strength, Defense, Experience points, and Gold
;   in Hand.

  @if &N11 > 32000 7              ; Storage value for Max HitPoints stat
    @set &N11 to 32000
  @endif 7

  @if &N8 > 32000 8               ; Storage value for Strength Points stat
    @set &N8 to 32000
  @endif 8

  @if &N20 > 32000 9              ; Storage value for Defense points stat
    @set &N20 to 32000
  @endif 9

  @if &N18 > 2000000000 10        ; Storage value for Gold in Hand
    @set &N18 to 2000000000
  @endif 10

  @if &N22 > 2000000000 11        ; Storage value for Experience points
    @set &N22 to 2000000000
  @endif 11
;
@writeln
@writeln    `@ - - - - - - - - - - - - - - - - - - - - - - - -
@writeln    `!Max HitPoints `%raised to `$&N11 `%points.
@writeln    `!Strength points `%are currently `$&N8 `%points.
@writeln    `!Defense points `%raised to `$&N20 `%points. `%

; Display if player received Gold for Temporary HP healed.
; --------------------------------------------------------------
@if &N17 > 0 12                   ; N17 is amount of Gold payment
  @begin
    @writeln    `$ - - - - - - - - - - - - - - - - - - - - - - -
    @writeln    `%Temporary HitPoints healed:  Granted `$&N17 `!Gold coins.
    @writeln    `!You now have `$&N18 `0Gold coins `!in your Gold bag.
  @end
@else 12         ; 04/12/05: added identifier 12.
  @begin
    @math &N18 = &Pgo + 0         ; Store current Gold in Hand.
    @writeln    `! - - - - - - - - - - - - - - - - - - - - - - -
    @writeln
    @writeln      `%No Gold was paid for `0Temporary Hitpoints `%today.
    @writeln    `%You currently have`$ &N18 `!Gold in Hand.
  @end
@endif 12

; Display if player was granted Experience Points:
; --------------------------------------------------------------
@writeln
@if &N21 > 0 13         ; N21 is amount of Experience points granted
  @begin
    @writeln    `! - - - - - - - - - - - - - - - - - - - - - - -
    @writeln    `%Wisdom granted by `2Nice Hag:  `$&N21 `!Points.
    @writeln    `%You now have `$&N22 `!Experience Points.
    @writeln    `@ - - - - - - - - - - - - - - - - - - - - - - -
  @end
@else 13           ; 04/12/05: added identifier 13
  @begin
    @writeln    `! - - - - - - - - - - - - - - - - - - - - - - -
    @writeln      `%No `0Experience Points `%were granted today.
    @writeln    `%You currently have  `$&N22 `!Experience Points.
    @writeln    `@ - - - - - - - - - - - - - - - - - - - - - - -
  @end
@endif 13

; -------------------------------------------------------------------
; Note: 12/20/03: even if script shows a value is over LORD's limits,
; the LADY script engine appears to be adjusting over-range stats
; downward automatically when it returns control of player's stats
; back to LORD in the Forest.
; -------------------------------------------------------------------

@writeln
@hitakey                ; Needed for LORD 4.06 compatibility.

@endquest

; ===============================================================
; Summary: You rescue an old lady who got lost in the forest, and
; take her home.  You find her sister is the Old Hag, and are given
; various rewards for being kind to Old Ladies.  Rewards include
; 1-2 new Max HitPoints, 7 Defense points, Free Healing, Experience
; points, and Gold.  What you receive depends on various factors.
;
; 09/10/04: Color code tweaking.  Changed Hag/Sarah quotation wording to
;           players so that they display consistently in Light Cyan.
;           Changed version from 1.23 to 1.25.
; 12/05/04: Renamed script label No_MaxHP_Reward to Hag_NoReward.
;           Renamed script label Hag_Points to Hag_Wisdom.
;           Changed version from 1.25 to 1.27.
;
; ===================================================================
; v1.10 - Awards Experience points to players, who didn't receive
; some in "No Healing needed" section.  v1.12 - Exp. points awards
; formulas revised, based on user's level.  "No Healing" reward
; changed to 5 Strength points * Level formula.  v1.14 - Added
; stats info for user's Strength points status.  v1.15 - text
; rewording and bug fixes.  v1.16 - Changed script label names.
; Rewards change: 3 Strength points per level.  5 Defense points.
; v1.17: Tested under LORD 4.06 for some scenarios, so far.
; v1.18: Handling of LORD 4.07 beta problem with over-range stats.
; 03/12/2003: Worked on color coding for some name usage spots.
; ----------------------------------------------------------------
;
; http://www.fidotel.com/public/camelot/LordApps/hag200.zip
; -- The Nice Hag v2.00 LORD IGM is available for usage publicly.
; -- First version of IGM was released on May 06th, 2003.
;
; http://www.fidotel.com/public/camelot/LordApps/hag210.zip
; -- 06/04/03: public release of The Nice Hag v2.10 LORD IGM.
;
; http://www.filegate.net/camelot/lordfile/hag214.zip - 10/07/03 note.
; -- The Nice Hag v2.14 LORD IGM.  Released on Oct. 03, 2003.
;
; http://www.filegate.net/camelot/lordfile/hag230.zip - 09/10/04 note.
; -- The Nice Hag v2.30 LORD IGM.  Released on 03-25-2004.
;
; ---------------------------------------------------------------------
: v1.20: 05/12/03. Fixed issue with script awarding too much Gold
;   for Temporary HitPoints to low-level players.
; 05/27/03: v1.21 - color code work, wording changes.
;
; ---------------------------------------------------------------------
; 12/20/03: v1.22 - handling of over-range values like Max HitPoints.
;           Moved other comment notes down to ending of script file.
; 12/21/03: v1.23 - Updated Experience points reward amounts, Levels 6-12.
;           Added ending notation about tough monsters to watch out for.

; 04/12/05: Added number identifier to the @else statements.
; 04/12/05:  Changed to version 1.30. Donald.
; 07/24/05: Added INSTALL and UNINSTALL sections to script.

; 03/21/07: v1.35. Added Fix_Bad_Stats section at start of script
;           which resets Over-Range Gems, Hitpoints, Max HitPoints,
;           Defense, Experience, Gold in Hand, and Strength stats
;           down to either 32,000 or 2 Billion (Gold/Exp).
;
; 05/15/07: Deleted temporary debug lines from March 21 work.

; 05/31/07: Fixed event where Hitpoints are at Zero, and script would
;           heal player -- but it didn't tell them about situation.
;           This CAN'T happen in LORD v4.07+, but can in prior versions.
; 05/31/07: v1.37: Revised Email/WWW info;  Changed version #.