; Goofy events by Gordon Lewicky, Sysop - Milky Way, 1:153/307
; 16 Jun/02
;   Version 1.10. Use of number identifiers with @else entries. DGT.
;
; This event was written and tested using Lord v4.07á 31 Mar/02 but
; any commands/vars are from previous Lords. This supports v4.05 & up. 
;
; DRAGONPOOP - Wandering thru the forest you slip on some dragon poop.
;              1 of 6 things can happen.
;              You fall away from the poop and gain 10% experience
;              You land in the poop and lose 1 forest fight due to clean up
;              You sprain your arm and lose 10% hit points
;              You sprain both ankles and lose 20% hit points
;              You break your arm and lose 30% hit points
;              Or you break your neck and die, cursing the dragon poop. :)
;
; HORNY      - You see your sweetheart's face in the clouds and get horny.
;              You are able to write romantic mail, even if you have written.
;
; SEXCHANGE  - You come across the faeries but this time they are really angry.
;              They change your sex for spying on them again.
;
; GRIZELDA   - Grizelda has been feeling down lately since nobody loves
;              her. In her own way, she is looking for love and has
;              decided that kids will be the only ones that will offer
;              her the unfettered love she so despatately needs.
;              Thus, she feels that she must steal kids to fulfill
;              her needs since nobody will become romantically involved
;              with her, and... well.... you know! ;)
;              The intent of this event is to keep kid ownership down to
;              a reasonable limit of 10 kids and to also deduct the amount
;              of forest fights gained from any kids over the 10 limit.
;
@#DRAGONPOOP
@display
`c  `%Event In The Forest`0
`l

  `2Wandering along, your foot suddenly slips on some greasy,
  slimey, stinky `@dragon poop`2. Your feet go flying out from under
  you as you flip in the air and land on your back with a splat!

@enddisplay
@hitakey
@set &N1 to &rnd5
@case &N1 1
0: @begin
     @math &N2 = &Pex - 0
     @math &N3 = &N2 / 10
     @math &N4 = &N2 + &N3
     @set &Pex to &N4
     @writeln
     @writeln `2You land with a wooof, but are otherwise unharmed.
     @writeln You also landed away from the poop so a lesson was learned.
     @writeln `9Watch your step in the forest at all times.
     @writeln The `@dragon `9is always nearby. Even his `@poop `9is dangerous!
     @writeln
     @writeln `0 You gain &N3 experience.
   @end

1: @begin
     @math &N2 = &Pff - 0
     @math &N3 = &N2 - 1
     @if &N3 < 0 1
       @begin
         @set &N3 to 0
       @end
     @endif 1
     @set &Pff to &N3
     @writeln
     @writeln `2You land with a splat right in the `@dragon poop`2!
     @writeln You reek and are covered with guk. You wander over to a stream
     @writeln to wash away the stench and crap.
     @writeln
     @writeln `0You lose 1 forest fight cleaning yourself up.
   @end

2: @begin
     @math &N2 = &Pht - 1
     @math &N3 = &N2 / 10
     @math &N4 = &N2 - &N3
     @set &Pht to &N4
     @writeln
     @writeln `2You land with a crunch and sprain your arm!
     @writeln
     @writeln `0You lose &N3 hit points!
   @end

3: @begin
     @math &N2 = &Pht - 0
     @math &N3 = &N2 / 10
     @math &N4 = &N3 * 2
     @math &N5 = &N2 - &N4
     @set &Pht to &N5
     @writeln
     @writeln `2You land with a crunch and sprain both ankles!
     @writeln
     @writeln `0You lose &N4 hit points!
     @end

4: @begin
     @math &N2 = &Pht - 0
     @math &N3 = &N2 / 10
     @math &N4 = &N3 * 3
     @math &N5 = &N2 - &N4
     @set &Pht to &N5
     @writeln
     @writeln `2You land with a crunch and break your arm!
     @writeln
     @writeln `0You lose &N4 hit points!
   @end

5: @begin
     @set &Pht to 0
     @set &Pdd to true
     @writeln
     @writeln `2You land striking a rock with your head. Your neck breaks!
     @writeln You are above and looking down at your broken body.
     @writeln
     @writeln `0Suddenly you realize that you are dead!
     @writeln
     @writeln `2Your ghost cries out `@Damn you Red Dragon and your slimey poop!
   @end
@endcase 1

; end of event
@writeln `2
@hitakey
@endquest

@#HORNY
@display
`c  `%Event In The Forest`0
`l

  `2Wandering along, dreaming of your previous romantic encounter,
  you gaze up in the sky and see a cloud that looks just like your
  sweetheart's face!

  Your blood starts to race and suddenly you are HORNY!

  You think that writing some romantic mail after your forest fights,
  is a good idea!

@enddisplay
@set &Pfl to false
; end of event
@writeln `2
@hitakey
@endquest

@#SEXCHANGE
@display
`c  `%Weird Happening In The Forest`0
`l

  `2Wandering along, you come across a large group of playful faeries,
  cavorting in the flowers. You try to sneak away, but they see you.

  `9"Hey there human!! We told you we do not like you spying on us!
  Mayhaps we should teach you a lesson. What do you think Mischievious?"

  "Most definately, Misdemeanor, most definately. Lemme think on it a bit."

  `2You try to run away, but the faeries completely surround you!

@enddisplay
@hitakey
@clrscr
@if &Psx is true 1
  @begin
    @writeln
    @writeln `2Mischievious looks you over, then breaks into a gleeful laugh.
    @writeln
    @writeln `9"Ooooo you are much too ugly to be a woman!" `2She throws some dust on you.
    @set &Psx to false
  @end
@else 1             ; 04/12/05: added identifier 1. DGT.
  @begin
    @writeln `2Mischievious looks you over, then breaks into a gleeful laugh.
    @writeln
    @writeln `9"Ooooo you are much too pretty to be a man!" `2She throws some dust on you.
    @set &Psx to true
  @end
@endif 1

; end of event
@writeln `2
@writeln You sneeze and then suddenly start feeling very strange.
@writeln
@writeln `@"Arggggggg"`2, you scream as you look down at your new body.
@writeln
@writeln Mischievious giggles, while Misdemeanor dances with glee.
@writeln
@writeln `9"I think you better go back to town and change your clothes. Hee hee..."
@writeln `2
@writeln And Misdemeanor pipes in laughing...
@writeln `9
@if &Psx is true 2
  @begin
  @writeln "I think your &Par should have two bumps up there on your chest!
  @writeln It sure looks like it is an awfully tight fit right now, and very,
  @writeln very, uncomfortable, I would guess! Hee hee..."
  @end
@else 2                ; 04/12/05: added identifier 2. DGT.
  @begin
  @writeln "I don't think your &Par should have those two bumps on your chest!
  @writeln It sure makes you look silly. And it looks like you need more room
  @writeln down below. It must be awfully tight there, right now! Hee hee..."
  @end
@endif 2    ; 04/12/05: changed to use identifier 2. DGT.

@writeln `$
@hitakey
@clrscr
@endquest

@#GRIZELDA
@display
`c  `%A horrific encounter with `#Violet `%in the forest`0
`l

  `#STOP, STOP, `%&nick`#. Did you hear the latest news about `@Grizelda`#?

  Apparently she was so depressed lately, since nobody loves her, that she 
  decided to take matters into her own hands! I hear she has been stealing
  kids from the parents while they were out here in the forest hunting the
  dragon. 

  Isn't that just HORRIBLE! I can't believe she would do such a thing.
  Nobody has been able to prove it as the kids cannot be found, but several
  parents have come home from the forest to find some of their kids missing!

  And lately, `@Grizelda`#, has been wearing a odd smirk on her face and
  she's been humming children's songs at work. I just can't believe it!
  None of my kids are missing, but maybe you better check to see if your's
  are!

  I better get back to the tavern, but I just thought you should know this.
@enddisplay
@if &Pki > 10 1
  @begin
  @math &N1 = &Pki + 0
  @math &N1 = &N1 - 10
  @set &Pki to 10
  @math &N2 = &Pff - &N1
  @if &N2 < 1 2
    @begin
    @set &N2 to 1
    @end
  @endif 2
  @set &Pff to &N2
  @end
@endif 1
@hitakey
@clrscr
@endquest

; 04/12/05: Added number identifier to the @else statements.
; 04/12/05:  added version 1.10 notation. Donald Tidmore.